Potentials and Motion

[Analog_Engine.git] / scripts / TP1 10.30 Linear Molecule.LACE

# TP1 10.30 Linear Molecule
# In a linear molecule of symmetric construction of type A-B-A the atoms are harmonically coupled and are performing small oscillations around the equilibrium positions.

# s1'' = -omega0^2*s1 + omega0^2*s2
# s2'' = -my (-omega0^2*s1 + omega0^2*s2 + omega0^2*s2 - omega0^2*s3)
# s3'' = omega0^2*s2 - omega0^2*s3

# NB: all integrators have to run with 100 nF capacitance, i.e. SLOW mode

# the following integrator has to be built up manually as THAT only has 5 integrators and we need 6
# iintegrate -s2' -> s2
define openamp (variable) -> result
   isum (variable) -> result
      connect (FB) -> GND

define iintegrate6 (variable) -> integral
   openamp variable -> integral
      connect SJ -> cp
   capacitor.100nF (integral) -> cp 
# this capacitance requires SLOW settings on all other capacitors. Better use an external 1 nF capacitor.

alias coefficient.1 -> coefficient.omega0^2_1 # omega0^2 for s1
alias coefficient.2 -> coefficient.omega0^2_2 # omega0^2 for s2 # same as omega0^2_1
alias coefficient.3 -> coefficient.omega0^2_3 # omega0^2 for s3 # same as omega0^2_1
alias coefficient.4 -> coefficient.my
coefficient.5 (-1) -> -s1_0 # initial position of s1
coefficient.6 (-1) -> -s3_0 # initial position of s3
# initial positon of s2, the central mass, is set to 0

iintegrate -omega0^2_1*s1, omega0^2_2*s2 -> -s1'   # input is s1''
iintegrate -s1' -> s1
   IC: -s1_0
invert s1 -> -s1
coefficient.omega0^2_1 (-s1) -> -omega0^2_1*s1

iintegrate -my*bracket -> -s2'   # input is s2''
iintegrate6 -s2' -> s2
coefficient.omega0^2_2 (s2) -> omega0^2_2*s2
isum -omega0^2_1*s1, omega0^2_2*s2, omega0^2_2*s2, -omega0^2_3*s3 -> -bracket
coefficient.my (-bracket) -> -my*bracket

iintegrate omega0^2_2*s2, -omega0^2_3*s3 -> -s3'   # input is s3''
iintegrate -s3' -> s3
  IC: -s3_0
invert s3 -> -s3
coefficient.omega0^2_3 (-s3) -> -omega0^2_3*s3

output s1 -> out.x
output s2 -> out.y
output s3 -> out.z